@echo off
rem 提升权限
%1 mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
cd /d "%~dp0"
rem 请务必保留原作者信息
:startCmd
echo - MySql
echo 1、安装 MySql 服务
echo 2、卸载 MySql 服务
echo 3、重启 MySql 服务
echo - PHP
echo 4、安装 PHP 服务
echo 5、卸载 PHP 服务
echo 6、重启 PHP 服务
echo - Nginx
echo 7、安装 Nginx 服务
echo 8、卸载 Nginx 服务
echo 9、重启 Nginx 服务
echo - 一键操作
echo i、安装全部服务
echo u、卸载全部服务
echo - 其他
echo e、退出脚本
echo a、关于脚本

set /p a=请输入选择：
if "%a%"=="" Goto exit
if "%a%"=="e" Goto exit
if "%a%"=="a" Goto about
if "%a%"=="i" Goto installAll
if "%a%"=="u" Goto uninstallAll
if "%a%"=="1" Goto m1
if "%a%"=="2" Goto m2
if "%a%"=="3" Goto m3
if "%a%"=="4" Goto p1
if "%a%"=="5" Goto p2
if "%a%"=="6" Goto p3
if "%a%"=="7" Goto n1
if "%a%"=="8" Goto n2
if "%a%"=="9" Goto n3

rem 退出脚本
:exit
	exit
goto end

rem 关于脚本
:about
	echo ----------
	echo 作者：zgcwkj
	echo 博客：blog^.zgcwkj^.cn
	echo 时间：2022-10-31
	echo ----------
goto end

rem 安装 MySql 服务
:m1
	echo 安装服务
	"%~dp0\mysql\bin\mysqld.exe" -install mysqlserver
	echo 服务安装完成

	echo 启动服务
	net start mysqlserver
	echo 服务启动完成
goto end

rem 卸载 MySql 服务
:m2
	echo 停止服务
	net stop mysqlserver
	echo 服务停止完成

	echo 卸载服务
	"%~dp0\mysql\bin\mysqld.exe" -remove mysqlserver
	echo 服务卸载完成
goto end

rem 重启 MySql 服务
:m3
	echo 重启服务
	net stop mysqlserver
	net start mysqlserver
	echo 服务重启完成
goto end

rem 安装 PHP 服务
:p1
	echo 安装服务
	"%~dp0\php\xxfpmW\winsw.exe" install
	echo 服务安装完成

	echo 启动服务
	net start phpserver
	echo 服务启动完成
goto end

rem 卸载 PHP 服务
:p2
	echo 停止服务
	net stop phpserver
	echo 服务停止完成

	echo 卸载服务
	"%~dp0\php\xxfpmW\winsw.exe" uninstall
	echo 服务卸载完成
goto end

rem 重启 PHP 服务
:p3
	echo 重启服务
	net stop phpserver
	net start phpserver
	echo 服务重启完成
goto end

rem 安装 Nginx 服务
:n1
	echo 安装服务
	"%~dp0\nginx\winsw.exe" install
	echo 服务安装完成

	echo 启动服务
	net start nginxserver
	echo 服务启动完成
goto end

rem 卸载 Nginx 服务
:n2
	echo 停止服务
	net stop nginxserver
	echo 服务停止完成

	echo 卸载服务
	"%~dp0\nginx\winsw.exe" uninstall
	echo 服务卸载完成
goto end

rem 重启 Nginx 服务
:n3
	echo 重启服务
	net stop nginxserver
	net start nginxserver
	echo 服务重启完成
goto end

rem 安装全部服务
:installAll
	echo 安装 MySql 服务
	"%~dp0\mysql\bin\mysqld.exe" -install mysqlserver
	net start mysqlserver
	
	echo 安装 PHP 服务
	"%~dp0\php\xxfpmW\winsw.exe" install
	net start phpserver
	
	echo 安装 Nginx 服务
	"%~dp0\nginx\winsw.exe" install
	net start nginxserver
	echo 安装完成
goto end

rem 卸载全部服务
:uninstallAll
	echo 卸载 Nginx 服务
	net stop nginxserver
	"%~dp0\nginx\winsw.exe" uninstall
	
	echo 卸载 PHP 服务
	net stop phpserver
	"%~dp0\php\xxfpmW\winsw.exe" uninstall
	
	echo 卸载 MySql 服务
	net stop mysqlserver
	"%~dp0\mysql\bin\mysqld.exe" -remove mysqlserver
	echo 卸载完成
goto end

:end

rem 清空输入信息
set a=e
rem 延时清空
timeout /T 3 /NOBREAK
rem 清空输出
cls
rem 跳转到顶端
goto startCmd
